Просмотр исходного текста страницы Настройка экспорта в YML Яндекс-маркет

Для настройки экспорта в YML, первое что необходимо сделать, это в модуле "Обмен данными", во вкладке "Экспорт" создать сценарий экспорта, указав формат экспорта: "Каталог в формате Яндекс-маркет(yml)", также указав разделы каталога, которые необходимо экспортировать. Произведя экспорт в YML и указав вариант "Получить ссылку на результат экспорта", мы указываем полученную ссылку в аккаунте Яндекс-Маркета, ссылка примерно следующего вида:
<pre>
_http://ваш_сайт/admin/exchange/get_export/27697/?as_file=0
</pre>

Также указываем логин/пароль пользователя, у которого в настройках, для блока "Обмен данными" стоит галка "Доступ к экспорту данных по http", либо можно просто для пользователя "Гость" поставить эту галку, тогда логин/пароль не надо будет указывать.

В настройках сценария экспорта можно прописать значение для параметра "Время кэширования результатов экспорта (в минутах)", это будет означать, что в течении времени между первым экспортом данных (time = X) и временем X+указанное_значение, данные будут браться из кэша, допустим из файла sys-temp/export/27697.xml. Каждый раз новый файл с данными формироваться не будет, т.е. необходимо учитывать, что при изменении цены товара на сайте, может возникнуть момент, что в Яндекс-маркет не сразу поступят обновленные данные, когда он их будет запрашивать по ссылке.

Теперь перейдем к настройкам формирования самого XML-файла для Яндекс-Маркета, ознакомиться с форматом YML, его требованиями, можно на данной странице: [http://partner.market.yandex.ru/legal/tt/ Описание формата данных YML]

Основным шаблоном формирования XML-файла для Яндекс-маркета является xsl/export/YML.xsl. Если необходимо изменить формирование итогового файла, то необходимо переназначать существующие шаблоны из оригинального файла, записывая их в xsl/export/custom/YML.xsl. При обновлении сайта шаблон xsl/export/YML.xsl перезаписывается.

В итоговом файле, значение элемента <name> берется  из первой вкладки модуля "Конфигурация", поле "Название сайта". У Яндекс-Маркета требование к этому полю, оно не должно быть длиной более 20 символов. В случаи надобности можно шаблон:
<pre>
<xsl:template match="umidump[@version='2.0']">
...
</xsl:template>
</pre>
скопировать в файл xsl/export/custom/YML.xsl, в основной узел "stylesheet", и уже там вручную прописать значение элемента <name>:
<pre>
<name><xsl:value-of select="meta/site-name" /></name>
</pre>

Одной из основных настроек которую требуется сделать, это исключить из экспорта неактивные объекты каталога в UMI.CMS, по мимо этого можно также исключить объекты каталога, которые находятся в неактивном разделе, но сами они могут быть активными.
Для этого скопируем шаблон:
<pre>
<xsl:template match="page[basetype/@method = 'object']">  
...
</xsl:template>
</pre>

в файл xsl/export/custom/YML.xsl, в основной узел stylesheet. Можно скопировать целиком или только те элементы, которые вы используете. Для примера рассмотрим следующий шаблон:
<source lang="xml">
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" 
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
 xmlns:php="http://php.net/xsl" 
 xmlns:udt="http://umi-cms.ru/2007/UData/templates" 
 extension-element-prefixes="php" 
 exclude-result-prefixes="xsl php udt">

  <xsl:template match="page[basetype/@method = 'object']">
    <xsl:param name="price" select="number(.//property[@name = 'price']/value)" />
    <xsl:param name="parentactive" select="document(concat('upage://',@parentId))/udata/page/@is-active" />
    <xsl:if test="$price &gt; 0 and $parentactive = '1'">
      <offer>
        <xsl:attribute name="available">
          <xsl:text>true</xsl:text>
        </xsl:attribute>
        <url>
          <xsl:value-of select="concat('http://', /umidump/meta/domain, @link)" />
        </url>
        <price>
          <xsl:value-of select="$price"/>
        </price>
        <currencyId>
          <xsl:choose>
            <xsl:when test="string-length($default-currency)">
              <xsl:value-of select="$default-currency" />
            </xsl:when>
            <xsl:otherwise>RUR</xsl:otherwise>
          </xsl:choose>
        </currencyId>
        <categoryId>
          <xsl:value-of select="@parentId"/>
        </categoryId>
        <xsl:if test=".//property[@name = 'image']/value != ''">
          <picture>
            <xsl:value-of select="concat('http://', /umidump/meta/domain, .//property[@name = 'image']/value)"/>
          </picture>
        </xsl:if>
        <delivery>true</delivery>
        <name>
          <xsl:value-of select="name"/>
        </name>
        <description>
          <xsl:value-of select="properties/group/property[@name = 'opisanie']/value"/>Цвет:
          <xsl:value-of select="properties/group/property[@name = 'vid']/value/item/@name" />; Вес:
          <xsl:value-of select="properties/group/property[@name = 'ves']/value" />;
          <xsl:apply-templates select="properties/group/property[@name = 'dvd']" />
        </description>
      </offer>
    </xsl:if>
  </xsl:template>

  <xsl:template match="property[value = '1']">
    <xsl:value-of select="title" />;
  </xsl:template>

  <xsl:template match="page[basetype/@method = 'object'][not(@is-active)]"></xsl:template>

</xsl:stylesheet>
</source>
в его начало мы добавили параметр:
<pre>
<xsl:param name="parentactive" select="document(concat('upage://',@parentId))/udata/page/@is-active" />
</pre>
и изменили следующий за ним if, т.е. добавили проверку на активность раздела в котором находится объект.
Экспорт неактивных объектов был исключен добавление шаблона:
<pre>
<xsl:template match="page[basetype/@method = 'object'][not(@is-active)]"></xsl:template>
</pre>

В данном примере считается, что в административной части нигде не указывается, сколько единиц того или иного товара осталось на складе, поэтому конструкция:
<pre>
<xsl:attribute name="available">
 <xsl:choose>
  <xsl:when test=".//property[@name = 'common_quantity']/value &gt; 0"><xsl:text>true</xsl:text></xsl:when>
 <xsl:otherwise><xsl:text>false</xsl:text></xsl:otherwise>
 </xsl:choose>
</xsl:attribute> 
</pre>

была заменена на:
<pre>
<xsl:attribute name="available">
    <xsl:text>true</xsl:text>
</xsl:attribute>
</pre>
Т.к. поле с изображением товара, в данном примере, имеет идентификатор image, то конструкция:
<pre>
<xsl:if test=".//property[@name = 'photo']/value != ''">
 <picture>
   <xsl:value-of select="concat('http://', /umidump/meta/domain, .//property[@name = 'photo']/value)"/>
 </picture>
 </xsl:if>
</pre>

была заменена на:
<pre>
<xsl:if test=".//property[@name = 'image']/value != ''">
 <picture>
  <xsl:value-of select="concat('http://', /umidump/meta/domain, .//property[@name = 'image']/value)"/>
 </picture>
</xsl:if>
</pre>

С учетом того, что доставка имеется, была добавлена строка:
<pre>
<delivery>true</delivery>
</pre>

Блок описание (<description >) был оформлен следующим образом:
<pre>
<description>
        <xsl:value-of select="properties/group/property[@name = 'opisanie']/value"/>
        Цвет: <xsl:value-of select="properties/group/property[@name = 'vid']/value/item/@name" />;
        Вес: <xsl:value-of select="properties/group/property[@name = 'ves']/value" />;
        <xsl:apply-templates select="properties/group/property[@name = 'dvd']" />
<description>
</pre>

Поле Цвет имеет тип "Выпадающий список", поле Вес – "Строка". Для понимания запросов с помощью которых берутся те или иные значения, необходимо иметь представление об XSLT. UMI.CMS формирует XML-Данные в формате [http://api.umi-cms.ru/umiDump20.html UMIDump2.0], с помощью нашего XSL-Шаблона мы трансформируем один XML-Файл в другой. Узел <page> в UMIDump, практически идентичен xml-данным полученным следующим образом: _http://ваш_сайт/upage/47 , используется протокол [http://help-dev.umi-cms.ru/chapter.XSLTTemplates.Upage.html upage ]
Данный вызов:
<pre>
<xsl:apply-templates select="properties/group/property[@name = 'dvd']" />
</pre>
и сам шаблон:
<pre>
<xsl:template match="property[value = '1']">
	<xsl:value-of select="title" />;
</xsl:template>
</pre>
служат для проверки поля типа чекбокс, с идентификатором 'dvd', в случае если чекбокс установлен, будет выведено название данного поля.